Hallo zusammen,
bin seit März Verso-Besitzer und ärgere mich über die nicht vorhandene Ordnernavigation des Touch2. Warum dies nur beim CD-Betrieb möglich ist, weiß wohl nur der Toyota-Ingenieur. Egal. Ich habe auf meinem USB-Stick nun zusätzlich eine Batch-Datei liegen, um unter Windows eine Pseudo-Ordernavigation für das Touch2 vorbereiten zu können: Ich lege für jeden Ordner eine Playlist (m3u) an. Diese kann am Touch2 ausgewählt werden. Die Playlistnamen orientieren sich dabei an der Verzeichnisstruktur, aus "F:\Musike\Tolle_Musik\" würde dann eine Playlist mit dem Namen "Musike--Tolle_Musik.m3u" erzeugen. Es wird für jedes Verzeichnis, in dem wenigstens eine MP3 oder AAC-Datei gefunden wird, eine Playlist nach obigen Muster angelegt.
Nun ist es im Radio möglich, die Lieder auf Ordnerbasis anhören zu können - zumindest fast (die Hierarchie der ORdner geht natürlich flöten). Vielleicht hilft es einem von euch ja. Einfach rauskopieren und als GeneratePlaylist.cmd speichern. Sollte mit Windows >= 7 funktionieren.
@echo off
:::::::::::::::::::::::::::::::::::::::
:: GeneratePlaylist
::
:: Batch zur Erstellung von Playlists
:: in allen Unterverzeichnissen
::
:::::::::::::::::::::::::::::::::::::::
::Ermittlung des aktuellen root:
Set _rootdir="%cd%\
:: doppelte backslashes entfernen
SET _rootdir=%_rootdir:\\=\%
Echo Start in %_rootdir%
FOR /R "." %%G in (.) DO (
Pushd %%G
call :doAction "%%G"
Popd )
timeout /t 10
goto :eof
:doAction
:: gibt's hier MP3s oder AACs? Nein? Dann Ende
If Not Exist *.mp3 (If Not Exist *.aac goto :eof)
:: Generiere den Playlist-Namen
:: kompletter Pfad, vorne und hinten mit \."
SET _currdir=%1
SET _currdir=%_currdir:\."=%
::Vorbereiten des m3u-Dateinamens
:: 1. Root-Dir aus dem aktuellen Dir entfernen
CALL SET _result=%%_currdir:%_rootdir%=%%
:: 2. Backslash (\) ersetzen duch "-"
SET _result=%_result:\=-%
:: 3. Falls noch ein ".-" über ist --> löschen
SET _result=%_result:.-=%
:: 4. Dateiendung anheften
SET _result=%_result%.m3u
:: 5. Falls am Ende ein - steht, dieses auch noch entfernen
SET _result=%_result:-.m3u=.m3u%
echo Generiere Playlist "%_result%"
If exist *.m3u del *.m3u
:: Wichtig: hier wird die Codepage der Ausgabe umgestellt, sonst werden umlaute UTF8 kodiert - damit kommt das Radio nicht klar!
chcp 1252>nul
dir /b /o:n *.mp3 *.aac>"%_result%"
goto :eof
Alles anzeigen
Viele Grüße!